ΔΙΑΦΟΡΙΚΕΣ ΕΞΙΣΩΣΕΙΣ με το MATHEMATICA
Α.   ΔΕ 1ης Τάξης

ΓΕΝΙΚΗ ΛΥΣΗ - ΜΕΡΙΚΕΣ ΛΥΣΕΙΣ

Clear["Global`*"]

Ορισμός Διαφορικής Εξίσωσης

deq1 = y'[x] ==  
        Exp[-x] - y[x]/2
deq2 = y'[x] + y[x]/2 -  (E^(-x)) == 
        0
deq3 = 
      D[y[x], x] + y[x]/2 -  (E^(-x)) == 0

Γενική Λύση της Δ.Ε.

1ος Τρόπος

GeneralSolution = DSolve[deq1, y[x], x]

2ος Τρόπος

GeneralSolution = DSolve[deq1, y, x]

Ανάθεση της Λύσης σε εύχρηστη Συνάρτηση

φ[x_] = y[x]  /. GeneralSolution[[1]]

Απλοποίηση της λύσης

φ[x]  // Simplify

Μερικές λύσεις με ανάθεση τιμής στην σταθερά C
Ανάθεση τιμής στην σταθερά C[1]

Άμεση  Ανάθεση τιμής στην σταθερά C[1] - Λάθος

C[1] = 1
φ[x]

Αντικατάσταση της C[1] με μια σταθερά του χρήστη

φ[x_] = φ[x]  /. {C[1] -> c}

c = 1;
φ[x]

Σχεδίαση των λύσεων

Plot[φ[x], {x, -2, 5}]

Μια άλλη Λύση

c = 2
φ[x]

Πως θα σχεδιάσουμε και τις δύο λύσεις;

c = 1
φ1[x_] = φ[x]
c = 2
φ2[x_] = φ[x]
Plot[{φ1[x], φ2[x]}, {x, -2, 5}, 
      PlotStyle -> {RGBColor[1, 0, 0], RGBColor[0, 0, 1]}]

Πρόβλημα Αρχικών Τιμών

Δ.Ε. και Γενική λύση

Clear["Global`*"]
deq = y'[x] == 
        Exp[-x] - y[x]/2
GeneralSolution = DSolve[deq, y, x]

Προβλημα Αρχικών τιμών
πχ. Λύση που περνάει από το σημείο   y(0)=1/2

partialsolution = 
      DSolve[{deq, y[0] == 1/2}, y, x]
φ[x_] = y[x]  /. partialsolution[[1]]

Σχεδίαση της μερικής λύσης

Plot[φ[x], {x, -2, 5}]

Γενικό Προβλημα Αρχικών τιμών
πχ. Λύση που περνάει από το σημείο   y(0)=y0

partialsolution = 
      DSolve[{deq, y[0] == y0}, y, x]
φ[x_] = y[x]  /. partialsolution[[1]]

Σχεδίαση Μερικών λύσεων

φ1 = φ[x] /. 
          y0 -> -1;
φ2 = φ[x] /. 
          y0 -> 0;
φ3 = φ[x] /. 
          y0 -> 1;
Plot[{φ1,  φ2,  φ3}, {x, -2, 5}, 
      AxesLabel -> {"x", "y"}]

2oς τρόπος

solutions = 
      Table[φ[x] /. y0 -> k,  {k, -2, 2, 
          0.2}]
Plot[Evaluate[solutions], {x, -2, 5}]