Conservative Dynamical systems of 1DoF
Example: Eardrum Oscillations x''[t]=-x[t]-a x[t]^2

Β. Vector Field and Phase space portrait

Clear["Global`*"]

System definition for a=1/4, Potential and Energy functions

a=1/4
f[x_]=-x-a x^2
V= -∫f[x]\[DifferentialD]x
Plot[V,{x,-8,3}]
Energy[x_,y_]=(1/2)y^2+V

Vector field

f1=y;
f2=f[x];
graph1=VectorPlot[{f1,f2},{x,-6,3},{y,-3,3},VectorPoints->15, VectorScale->{0.03,1.5,None}, VectorStyle->Gray, Frame->None]

Phase space trajectories

Particular initial conditions

x0=1.5;
y0=0.1;
E1=Energy[x0,y0] 
Print["Energy of trajectory Ε=",E1]

graph2=ContourPlot[Energy[x,y]==E1,{x,-6,3},{y,-3,3}, ContourShading->False ]
(* graph2=ContourPlot[Energy[x,y],{x,-6,2},{y,-3,3}, Contours->{E1},ContourShading->False ] *)

Show[{graph1,graph2}, Frame->True]

Phase space portrait

ContourPlot[Energy[x,y],{x,-6,3},{y,-3,3}, ContourShading->False, Contours->20, PlotPoints->100]

Phase space trajectories at defined energy levels

e1=-4; e2=-2; e3=0; e4=0.5; e5=1; e6=2; e7=3; e8=4;
graph3=Plot[{e1,e2,e3,e4,e5,e6,e7,e8},{x,-7,3},PlotStyle->RGBColor[0,1,1]];
graph4=Plot[V,{x,-6,3}];
Show[{graph3,graph4}, PlotRange->All]

phasespace0=ContourPlot[Energy[x,y],{x,-6,3},{y,-3,3}, ContourShading->False, Contours->{e1,e2,e3,e4,e5,e6,e7,e8}, PlotPoints->100]

Separatrix

x0=x/.Solve[f[x]==0,x][[1]]   (* the unstable equilibrium point *)

Energy0u=Energy[x0,0]  (* energy of unstable equilibrium point *)
Plot[{V,Energy0u},{x,-7,3}]

separatrix=ContourPlot[Energy[x,y]==Energy0u,{x,-6,3},{y,-3,3}, ContourShading->False,  ContourStyle->Red, PlotPoints->100]

PhaseSpaceComplete=Show[phasespace0, separatrix,graph1]